24 янв. 2015 г.

Новые возможности в динамическом SQL в Oracle 12c (возврат "неявного" курсора)

В некоторых СУБД есть возможность вернуть из хранимой функции непосредственно набор данных. Например, в СУБД MS SQL Server возможен такой код хранимой процедуры на T-SQL:
CREATE PROCEDURE my_proc1
AS
BEGIN
 SELECT * FROM accounts_amounts WHERE Amount >= 20000
END
Далее, клиентские библиотеки, на стороне приложения, могут такой "неявный" курсор прочитать.

Как вы хорошо знаете, такой возможности в СУБД Oracle Database нет: хранимая процедура не может вернуть просто запрос. Необходим возврат ссылки на курсор (ref cursor): через OUT-переменную, либо как результат возвращаемый хранимой функцией.

Например:
CREATE OR REPLACE PACKAGE my_types IS
  TYPE
   Taccounts_amounts_cur is ref cursor;
END;
/

CREATE PROCEDURE my_proc1(v_xRes in out my_types.Taccounts_amounts_cur) IS
BEGIN
 OPEN v_xRes FOR 
   SELECT * FROM accounts_amounts WHERE Amount >= 20000;
END;
/

В общем-то, отсутствие в СУБД Oracle Database возможности вернуть из хранимой процедуры просто курсор, никак не мешала разработчикам приложений.
Тем не менее, это значительно усложняло процедуру миграции приложений на СУБД Oracle Database, с тех СУБД, где такая возможность присутствовала.

В СУБД Oracle Database 12c такая возможность появилась!
Это, конечно, потребовало адаптации клиентских библиотек доступа в Oracle Client. Начиная с Oracle Database Client 12c приложения, которые используют любой интерфейс доступа к СУБД (Oracle Call Interface, ODP.Net, JDBC), могут получать из СУБД такие "неявные" курсоры. Собственно на стороне СУБД, чтобы вернуть такой курсор, необходимо использовать новую процедуру RETURN_RESULT из пакета DBMS_SQL.

Эта процедура перегружена, и присутствует в двух вариантах:
  • для возврата слаботипизированной ссылки на курсор -
    PROCEDURE RETURN_RESULT(rc IN OUT SYS_REFCURSOR, to_client IN BOOLEAN DEFAULT TRUE);
  • для возврата курсора отрытого с помощью динамического SQL в пакете DBMS_SQL -
    PROCEDURE RETURN_RESULT(rc IN OUT INTEGER, to_client IN BOOLEAN DEFAULT TRUE);
Параметр to_client определяет возможность возвращения курсора непосредственно сразу клиентcкому приложению, либо в другую хранимую процедуру PL/SQL. Хранимая процедура может вернуть таким образом не один курсор, а несколько - может вызвать процедуру RETURN_RESULT несколько раз. Определим хранимую процедуру, которая возвращает курсор подобным образом в клиентское приложение:
SQL> create or replace procedure test_dyn3 is
  v_xCursor    integer;
  v_xRowCount  integer;
begin
  v_xCursor := dbms_sql.open_cursor;

  dbms_sql.parse(c                  => v_xCursor,
                 statement          => 'select * from dual',
                 language_flag      => DBMS_SQL.NATIVE);

  v_xRowCount := dbms_sql.execute(c => v_xCursor);

  dbms_sql.return_result(v_xCursor,true);
end;
/

Procedure created.

Попробуем вызвать нашу процедуру в среде утилиты SQL*Plus:
SQL> exec test_dyn3;

PL/SQL procedure successfully completed.

ResultSet #1

D
-
X

SQL>
Как Вы можете убедиться: утилита SQL*Plus версии 12с "понимает" такой вид курсора, и просто выводит его содержимое на свою консоль.
Эта возможность появилась в версии 12с этой утилиты. Если курсор возвращается таким образом из динамического SQL, то чтобы его получить внутри вызываемого блока PL/SQL, предназначена еще одна новая процедура пакета DBMS_SQL - GET_NEXT_RESULT. Эта процедура также перегружена и имеет два варианта:
  • для получения слаботипизированной ссылки на курсор -
    PROCEDURE GET_NEXT_RESULT (c IN INTEGER, rc OUT SYS_REFCURSOR);
  • для получения курсора отрытого с помощью динамического SQL в пакете DBMS_SQL -
    PROCEDURE GET_NEXT_RESULT (c IN INTEGER, rc OUT INTEGER);;
Для того чтобы, иметь возможность получения таких "неявных" курсоров, вызов процедуры OPEN_CURSOR должен быть выполнен с новым параметром treat_as_client_for_results равным значению TRUE, по умолчанию значение этого параметра равно FALSE. Немного перепишем нашу процедуру test_dyn3 указав в функции возврата курсора значение параметра to_client равным FALSE:
SQL> create or replace procedure test_dyn3 is
  v_xCursor    integer;
  v_xRowCount  integer;
begin
  v_xCursor := dbms_sql.open_cursor;

  dbms_sql.parse(c                  => v_xCursor,
                 statement          => 'select * from dual',
                 language_flag      => DBMS_SQL.NATIVE);

  v_xRowCount := dbms_sql.execute(c => v_xCursor);

  dbms_sql.return_result(v_xCursor,false);
end;
/

Procedure created.
Теперь вызовем нашу процедуру через динамический SQL, и попробуем получить и вывести на экран содержимое курсора:
SQL> DECLARE
  v_xCursor          integer;
  v_xRowCount        integer;

  v_xReturnCursor    integer;
  v_xResult          dual.dummy%type;
  v_xReturnRefCursor sys_refcursor;
BEGIN
  v_xCursor := dbms_sql.open_cursor(treat_as_client_for_results => true);

  dbms_sql.parse(v_xCursor, 'BEGIN test_dyn3(); END;', dbms_sql.native);

  v_xRowCount := DBMS_SQL.EXECUTE(v_xCursor);
 
  dbms_sql.get_next_result(v_xCursor, v_xReturnCursor);

--Для удобства превращаем полученный курсор в ссылку на курсор (sys_refcursor)
  v_xReturnRefCursor := dbms_sql.to_refcursor(v_xReturnCursor);

  FETCH v_xReturnRefCursor 
    INTO v_xResult;
 
  dbms_output.put_line('Result: ' || v_xResult);
 
  dbms_sql.close_cursor(v_xCursor);
END;
/
Result: X

PL/SQL procedure successfully completed.

SQL>
Мы рассмотрели еще одну новую возможность Oracle Database 12c в области динамического SQL - возможность непосредственного возврата курсоров из хранимых процедур.
На мой взгляд, эта новая возможность в основном востребована при миграции приложений с других СУБД, которые уже поддерживают эту технологию, на СУБД Oracle Database. Поскольку в этом случае значительно снижается объем работ по адаптации кода приложения под СУБД Oracle.

9 янв. 2015 г.

Новые возможности в динамическом SQL в Oracle 12c (определение схемы по умолчанию)

Следующая новая возможность в динамическом SQL тоже связана с процедурой PARSE пакета DBMS_SQL.
До Oracle Database 12c, если в тексте запроса или анонимного PL/SQL-блока в имени объекта не была явна указана схема, то будет использована текущая схема.
Для программных единиц PL/SQL (пакетов, процедур, функций и т.д.) созданных с правами создателя, это будет схема в которой происходила компиляция, для созданных с правами вызывающего - схема пользователя, под которым происходит вызов динамического SQL.

Начиная с Oracle Database 12c, можно четко контролировать схему в имени объекта, для которых она была не указана в динамическом SQL:
[oracle@rac1 ~]$ sqlplus rscott/rtiger

SQL*Plus: Release 12.1.0.2.0 Production on Fri Jan 9 16:24:34 2015

Copyright (c) 1982, 2014, Oracle.  All rights reserved.

Connected to:
Oracle Database 12c Enterprise Edition Release 12.1.0.2.0 - 64bit Production
With the Partitioning, Real Application Clusters, Automatic Storage Management options

SQL> create or replace package body account_service as

  procedure deleteAccount(v_pId in number) is
    v_xCursor    integer;
    v_xRowCount  integer;
    v_xPLSQL_Str varchar2(1600);
  begin
    v_xPLSQL_Str := 'delete from accounts where id = :v_pId';

    v_xCursor := dbms_sql.open_cursor;
  
    dbms_sql.parse(c                  => v_xCursor,
                   statement          => v_xPLSQL_Str,
                   language_flag      => DBMS_SQL.NATIVE,
                   schema             => 'DATA_OWNER');
    dbms_sql.bind_variable(v_xCursor, ':v_pId', v_pId);       

    v_xRowCount := dbms_sql.execute(c => v_xCursor);

    dbms_sql.close_cursor(c => v_xCursor);    
  end;

end;
/

Package body created.
Важно отметить, что параметр SCHEMA в процедуре PARSE отвечает лишь за имя схемы, в которой происходит поиск объекта при парсинге. Выполнение динамического SQL происходит с правами той программной единицы PL/SQL, в которой происходит вызов пакета DBMS_SQL - с правами создателя, либо с правами вызывающего.

2 янв. 2015 г.

Новые возможности в динамическом SQL в Oracle 12c (выполнение кода в PDB)

Говоря о новых возможностях Oracle Database 12c, нельзя не упомянуть динамический SQL.
В этой области тоже появилось много новых и интересных возможностей.

  1. Выполнение кода в контексте произвольной PDB-базы
Безусловно, самой главной новой технологией, которая пришла вместе с Oracle 12c, являются мультиарендная архитектура баз данных (Multitenant database).
Поддержка контейнерной архитектуры не могла пройти мимо динамического SQL: в пакете DBMS_SQL появилась возможность выполнить произвольный код в контексте указанной подключаемой базы данных (PDB). В процедуре PARSE появился новый параметр CONTAINER, который указывает PDB-базу, в которой нужно выполнить соответствующий динамический SQL или PL/SQL-код:
  dbms_sql.parse(c                  => v_xCursor,
                 statement          => v_xPLSQL_Str,
                 language_flag      => DBMS_SQL.NATIVE,
                 container          => 'CRM');
В вышеприведенном примере, код содержащийся в переменной v_xPLSQL_Str будет выполнен в PDB-базе CRM.
Важно отметить следующее: такой динамический код может быть выполнен только когда текущая сессия находится в БД-контейнере (CDB$ROOT), и пользователь должен иметь права на доступ к соответствующей PDB, то есть должен быть common-пользователем.

Создадим common-пользователя и дадим ему доступ к всем PDB в контейнере:
[oracle@dbim cdb1]$ sqlplus / as sysdba

SQL*Plus: Release 12.1.0.2.0 Production on Sat Jan 2 07:04:01 2015

Copyright (c) 1982, 2014, Oracle.  All rights reserved.


Connected to:
Oracle Database 12c Enterprise Edition Release 12.1.0.2.0 - 64bit Production
With the Partitioning, OLAP, Advanced Analytics and Real Application Testing options

SQL> CREATE USER global$rscott1
   IDENTIFIED BY rtiger container=all;

User created.

SQL> grant connect, resource to global$rscott container=all;

Grant succeeded.
Для имени common-пользователя был использован нестандартный префикс (GLOBAL$, а не C##), поскольку параметр common_user_prefix был переопределен:
SQL> show parameter common

NAME         TYPE  VALUE
------------------------------------ ----------- ------------------------------
common_user_prefix       string  global$
Возможность переопределения префикса в именах common-пользователей появилась в патчсете 12.1.0.2.

Предположим, что в контейнере находятся три PDB-базы: ERM, CRM и DW. В каждой из этих БД есть процедура создания учетной записи клиента определенная в пакете account_service:
create or replace package account_service as

  v_gLastAuditMessage varchar2(128);

  procedure newAccount(v_pName        in varchar2,
                       v_pDescription in varchar2);

end;
И после создание учетной записи клиента происходит сохранение информации аудита в глобальной переменной v_gLastAuditMessage:
create or replace package body account_service as

  procedure newAccount(v_pName        in varchar2,
                       v_pDescription in varchar2) is
  begin
    --код специфичный для каждой PDB 
    ...  ...  ...  ...  ...  ...  

    v_gLastAuditMessage := 'Account "' || v_pName || '" created in pdb ' || sys_context('USERENV', 'CON_NAME');
  end;
  
end;
В root-контейнере мы можем создать процедуру создания учетных записей клиентов сразу в нескольких PDB, при этом реально в каждой PDB-базе будет выполняться именно свой прикладной код.
Рис.1 Инкапсуляция прикладной логики в cdb$root c помощью динамического SQL

Исходный код, иллюстрирующий вышеописанный подход, может выглядеть следующим образом:
[oracle@dbim cdb1]$ sqlplus / as sysdba

SQL*Plus: Release 12.1.0.2.0 Production on Sat Jan 2 07:45:16 2015

Copyright (c) 1982, 2014, Oracle.  All rights reserved.


Connected to:
Oracle Database 12c Enterprise Edition Release 12.1.0.2.0 - 64bit Production
With the Partitioning, OLAP, Advanced Analytics and Real Application Testing options

SQL>conn global$rscott/rtiger
Connected.

SQL> --in Root container:

SQL> create or replace type TArrayOfString as table of varchar(32);
/

Type created.

SQL> create or replace package account_service as

  procedure newAccount(v_pName        in varchar2,
                       v_pDescription in varchar2,
                       v_pContainers  in TArrayOfString);

end;
/

Package created.


--Бизнес-логика выполняется в каждой PDB:
SQL> create or replace package body account_service as

  procedure newAccount(v_pName        in varchar2,
                       v_pDescription in varchar2,
                       v_pContainers  in TArrayOfString) is
    v_xCursor    integer;
    v_xRowCount  integer;
    v_xPLSQL_Str varchar2(1600);
  begin
    v_xPLSQL_Str := 'begin account_service.newAccount(:v_pName, :v_pDescription); end;';

    v_xCursor := dbms_sql.open_cursor;
  
    for v_xContainerIndex in 1..v_pContainers.count
    loop
      dbms_sql.parse(c                  => v_xCursor,
                     statement          => v_xPLSQL_Str,
                     language_flag      => DBMS_SQL.NATIVE,
                     container          => v_pContainers(v_xContainerIndex));

      dbms_sql.bind_variable(v_xCursor, ':v_pName', v_pName);       
      dbms_sql.bind_variable(v_xCursor, ':v_pDescription', v_pDescription);

      v_xRowCount := dbms_sql.execute(c => v_xCursor);
    end loop;

    dbms_sql.close_cursor(c => v_xCursor);    
  end;

end;
/
Package body created.
Попробуем создать учетные записи клиентов сразу в трех подключаемых БД в контейнере:
SQL> exec account_service.newAccount('Scott Tiger','Scott Tiger demo',new TArrayOfString('ERP','CRM','DW'));

PL/SQL procedure successfully completed.
Теперь переключимся в конкретную PDB-бд и проверим контекст сессии (состояние переменной v_gLastAuditMessage):
SQL>  alter session set container=ERP; 

Session altered.

SQL>  set serveroutput on 
SQL>  exec dbms_output.put_line(account_service.v_gLastAuditMessage); 
Account "Scott Tiger" created in pdb ERP

PL/SQL procedure successfully completed.

SQL> alter session set container=CRM;

Session altered.

SQL>  set serveroutput on 
Account "Scott Tiger" created in pdb CRM

PL/SQL procedure successfully completed.
Как видите, в каждой PDB-бд поддерживается свой контекст сессии - значение глобальной переменной v_gLastAuditMessage имеет свое значение для каждой PDB. Вообще говоря, это три разные переменные, поскольку каждая PDB-бд имеет собственную реализацию пакета управления учетными записями клиентов - account_service.

В Oracle 12c динамический SQL позволяет на уровне контейнера CDB$Root проводить своеобразную "оркестровку" вашего прикладного кода реализованного внутри PDB-баз данных.